' -------------------------------------------------------------------------
'       From the book Inside Active Directory, ISBN 0-201-61621-1
'       Copyright (C) 2002 by Addison-Wesley
'       Script by Sakari Kouti (see http://www.kouti.com)
' You have a royalty-free right to use, modify, reproduce and distribute
' this script (and/or any modified version) in any way you find useful,
' provided that you agree that Addison-Wesley or Sakari Kouti has no
' warranty, obligations or liability for the script. If you modify
' the script, you must retain this copyright notice.
' -------------------------------------------------------------------------
Option Explicit

Dim objDSE, objConnection, objCommand, objRecordset, i

Set objDSE = GetObject("LDAP://rootDSE")

Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open

Set objCommand = CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection

objCommand.CommandText = _
	"<LDAP://" & objDSE.Get("defaultNamingContext") & ">" & _
	";(&(objectCategory=person)(sn=a*))" & _
	";distinguishedName" & _
	";SubTree"

Set objRecordset = objCommand.Execute

i = 0
If Not objRecordset.EOF Then
	While Not objRecordset.EOF
		i = i + 1
		WScript.Echo i & ": " & objRecordset.Fields("distinguishedName")
		objRecordset.MoveNext
	Wend
Else
	WScript.Echo "No objects"
End if

objRecordset.Close
objConnection.Close