' -------------------------------------------------------------------------
'       From the book Inside Active Directory, ISBN 0-201-61621-1
'       Copyright (C) 2002 by Addison-Wesley
'       Script by Sakari Kouti (see http://www.kouti.com)
' You have a royalty-free right to use, modify, reproduce and distribute
' this script (and/or any modified version) in any way you find useful,
' provided that you agree that Addison-Wesley or Sakari Kouti has no
' warranty, obligations or liability for the script. If you modify
' the script, you must retain this copyright notice.
' -------------------------------------------------------------------------
Option Explicit

Dim objDSE, objSchema, objChild, i

Set objDSE = GetObject("LDAP://rootDSE")
Set objSchema = GetObject("LDAP://" & _
	objDSE.Get("schemaNamingContext"))

i = 0
For Each objChild In objSchema
	If objChild.Class = "attributeSchema" Then
		If objChild.isMemberOfPartialAttributeSet Then
			i = i + 1
			WScript.Echo "Attr " & i & ": " & _
				objChild.Name  & " (" & _
				objChild.Get("lDAPDisplayName") & ")"
		End If
	End If
Next