' -------------------------------------------------------------------------
'       From the book Inside Active Directory, ISBN 0-201-61621-1
'       Copyright (C) 2002 by Addison-Wesley
'       Script by Sakari Kouti (see http://www.kouti.com)
' You have a royalty-free right to use, modify, reproduce and distribute
' this script (and/or any modified version) in any way you find useful,
' provided that you agree that Addison-Wesley or Sakari Kouti has no
' warranty, obligations or liability for the script. If you modify
' the script, you must retain this copyright notice.
' -------------------------------------------------------------------------
Option Explicit

Const WAIT_ON_RETURN = True
Const HIDE_WINDOW = 0
Const USER_ROOT_UNC = "\\dc1\users"
Const USER_ROOT_LOCAL = "D:\Users"

Call CreateHomeFolder("JackB")

Sub CreateHomeFolder(strUser)
	Dim WshShell, WshNetwork, objFS, objServer, objShare

	Set WshShell = Wscript.CreateObject("Wscript.Shell")
	Set WshNetwork = WScript.CreateObject("WScript.Network")
	Set objFS = CreateObject("Scripting.FileSystemObject")

	Call objFS.CreateFolder(USER_ROOT_UNC & "\" & strUser)

	Call WshShell.Run("cacls " & USER_ROOT_UNC & "\" & strUser & _
		" /e /g Administrators:F", HIDE_WINDOW, WAIT_ON_RETURN)
	Call WshShell.Run("cacls " & USER_ROOT_UNC & "\" & strUser & _
		" /e /g " & strUser & ":C", HIDE_WINDOW, WAIT_ON_RETURN)

	Set objServer = _
		GetObject("WinNT://sanao/dc1/LanmanServer")
	Set objShare = objServer.Create("fileshare", strUser)
	objShare.Path = USER_ROOT_LOCAL & "\" & strUser
	objShare.MaxUserCount = -1		'unlimited number of users
	objShare.SetInfo
	Set objShare = Nothing
End Sub